plugins {
    id 'java-library'
    id 'signing'
    id 'maven-publish'
    id('io.github.gradle-nexus.publish-plugin') version '1.1.0'
}

group 'com.sparrowwallet'
version '0.9.0'

sourceCompatibility = 17

repositories {
    mavenCentral()
}

dependencies {
    testImplementation group: 'junit', name: 'junit', version: '4.13.1'
}

java {
    withJavadocJar()
    withSourcesJar()
}

nexusPublishing {
    repositories {
        sonatype()
    }
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            from(components.java)
            pom {
                name = 'toucan'
                description = 'Java implementation of Lifehash'
                url = 'https://github.com/sparrowwallet/toucan'

                scm {
                    url = 'https://github.com/sparrowwallet/toucan'
                    connection = 'scm:git://github.com/sparrowwallet/toucan.git'
                    developerConnection = 'scm:git://github.com:sparrowwallet/toucan.git'
                }

                licenses {
                    license {
                        name = 'The Apache Software License, Version 2.0'
                        url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                    }
                }

                developers {
                    developer {
                        id = 'craigraw'
                        name = 'Craig Raw'
                        email = 'mail@sparrowwallet.com'
                    }
                }
            }
        }
    }
}

signing {
    sign publishing.publications.mavenJava
}